2025年12月26日 (五) 18:08 imported>ExultantEditor

2025-12-26T18:08:02Z

新页面

{{Infobox programming language
| name = GNU Smalltalk
| logo = GNU Smalltalk logo.svg
| logo size = 160px
| screenshot =
| caption =
| designer =
| developer = Steve Byrne（直到1.1.5）,<br/>Paolo Bonzini（自从1.6）<ref>{{cite web|url=https://github.com/bonzini/smalltalk/blob/master/AUTHORS|title=AUTHORS|access-date=2022-02-10|archive-date=2022-03-18|archive-url=https://web.archive.org/web/20220318225600/https://github.com/bonzini/smalltalk/blob/master/AUTHORS}}</ref>
| released = {{Start date and age|mf=yes|2003|01|12}}
| latest_release_version = 3.2.5<ref>{{cite web|url=https://git.savannah.gnu.org/cgit/smalltalk.git/log/?h=stable-3.2|title=index : smalltalk.git|access-date=2022-02-10|archive-date=2022-03-07|archive-url=https://web.archive.org/web/20220307080012/https://git.savannah.gnu.org/cgit/smalltalk.git/log/?h=stable-3.2}}</ref>
| latest_release_date = {{Release date and age|2013|03|04}}
| latest_preview_version =
| latest_preview_date =
| paradigm = [[面向对象程序设计|面向对象]], [[脚本语言#动态语言|脚本]]
| operating_system = [[Unix]]（[[Linux]], [[Cygwin]], [[Mac OS X]]/[[Darwin (操作系统)|Darwin]]）
| platform =
| family = [[Smalltalk]]
| influenced = [[Smalltalk|ANSI Smalltalk]]
| file ext = .st
| license = [[GNU General Public License|GPL]]（针对虚拟机） + [[GNU Lesser General Public License|LGPL]]（针对类库和映像）
| website = [https://www.gnu.org/software/smalltalk/ https://www.gnu.org/software/smalltalk/]
}}

'''GNU Smalltalk'''是[[Smalltalk]][[编程语言]]的[[GNU计划]]实现。

这个实现不同于其他Smalltalk环境，使用文本文件作为程序输入，并将其内容解释为Smalltalk代码<ref>{{cite web|url=https://www.gnu.org/software/smalltalk/manual/gst.html#Syntax|title=Syntax of GNU Smalltalk|access-date=2022-02-09|archive-date=2022-02-18|archive-url=https://web.archive.org/web/20220218214218/https://www.gnu.org/software/smalltalk/manual/gst.html#Syntax}}</ref>。在这种方式下，GNU Smalltalk表现得更像是一种解释器，而非传统Smalltalk方式下的一种环境<ref>{{cite web|url=http://www.canol.info/books/computer_programming_using_gnu_smalltalk/|title=Computer Programming using GNU Smalltalk|access-date=2022-02-09|archive-date=2022-04-06|archive-url=https://web.archive.org/web/20220406043923/http://www.canol.info/books/computer_programming_using_gnu_smalltalk/}}</ref>。GNU Smalltalk包括了对很多自由软件库的[[绑定]]，包括[[SQLite]]、[[SDL|libSDL]]、[[cairo]]、[[gettext]]和{{le|Expat (库)|Expat (library)|Expat}}等<ref>{{cite web|url=https://www.gnu.org/software/smalltalk/manual/gst.html#Packages|title=Packages|access-date=2022-02-09|archive-date=2022-02-18|archive-url=https://web.archive.org/web/20220218214218/https://www.gnu.org/software/smalltalk/manual/gst.html#Packages}}</ref>。

==简单例子==
下面的例子可工作在GNU Smalltalk 3.0和以后版本上。经典的[[Hello World|Hello, World!]]例子：

<syntaxhighlight lang="smalltalk">
'Hello, World!' displayNl
</syntaxhighlight>

GNU Smalltalk声明了三个文件：<code>stdin</code>、<code>stdout</code>和<code>stderr</code>，作为文件串流类（<code>FileStream</code>）的全局实例，并绑定了适合传递给C虚拟机的值。对象类（<code>Object</code>）定义了特有于GNU Smalltalk的四个方法：<code>print</code>、<code>printNl</code>、<code>store</code>和<code>storeNl</code>。它们对接收者做一次<code>printOn:</code>或<code>storeOn:</code>至<code>Transcript</code>对象。这个对象是文本搜集器类（<code>TextCollector</code>）的唯一实例，它通常将写操作委托给<code>stdout</code>。

一些基本的Smalltalk代码：

<syntaxhighlight lang="smalltalk">
"所有东西，包括一个文字，都是一个对象，所以如下可行:"
-199 abs. "199"
'gst is cool' size. "11"
'Slick' indexOf: $c. "4"
'Nice Day Isn''t It?' asLowercase asSet asSortedCollection asString "' ''?acdeinsty'"
</syntaxhighlight>
两个<code>"</code>包围的是注释；<code>$c</code>是字符常量<code>c</code>；两个<code>'</code>包围的是字符串，字符串中的<code><nowiki>''</nowiki></code>是<code>'</code>的[[转义序列]]。

==搜集==
构造和使用一个[[数组]]：

<syntaxhighlight lang="smalltalk">
a := #(1 'hi' 3.14e0 1 2 (4 5)).

a at: 3. "3.14"
a reverse. "((4 5) 2 1 3.14 'hi' 1)"
a asSet "Set(1 'hi' 3.14 2 (4 5))"
</syntaxhighlight>

构造和使用一个[[散列表]]，它是散列搜集类（<code>HashedCollection</code>）的子类即字典类（<code>Dictionary</code>）的实例：

<syntaxhighlight lang="smalltalk">
hash := Dictionary from: { 'water' -> 'wet'. 'fire' -> 'hot' }.
hash at: 'fire' "'hot'".

hash keysAndValuesDo:
[ :k :v | ('%1 is %2' % { k. v }) displayNl ].
"=> fire is hot
=> water is wet"

"删除 'water' -> 'wet'"
hash removeKey: 'water'
</syntaxhighlight>

GNU Smalltalk在字符串类（<code>String</code>），和作为它的超类的数组式搜集类（<code>ArrayedCollection</code>）之间，又介入了特有的字符数组类（<code>CharacterArray</code>），它的<code>%</code>方法，将其接收者中具有的特殊[[转义序列]]，替换为由参数给出的搜集中的元素，其中<code>%n</code>被替代为这个搜集的第<code>n</code>个元素（<code>1 <= n <= 9</code>或<code>A <= n <= Z</code>）。这里给它的搜集，是在<code>{</code>和<code>}</code>之间包围的，当前Smalltalk变体一般都提供的动态数组，其中的元素可以在运行时间求值。

==块和迭代器==
参数传递到是为[[闭包 (计算机科学)|闭包]]的一个块：

<syntaxhighlight lang="smalltalk">
"remember被绑定到一个块."
remember := [ :name | ('Hello, %1!' % { name }) displayNl ].

"时机成熟时 -- 调用这个闭包!"
remember value: 'world'
"=> Hello, world!"
</syntaxhighlight>

从一个方法返回由两个闭包构成的一个数组：
<syntaxhighlight lang="smalltalk">
Integer extend [
asClosure [
| value |
value := self.
^{ [ :x | value := x ]. [ value ] }
]
].

blocks := 10 asClosure.
setter := blocks first.
getter := blocks second.
getter value. "10"
setter value: 21. "21"
getter value "21"
</syntaxhighlight>
这里用<code>extend</code>为现存的类扩展新方法是GNU Smalltalk特有的语法。

下面的[[考拉兹猜想]]例子，展示将两个块传递给接收者，并将结果信息发送回到调用者：

<syntaxhighlight lang="smalltalk">
Integer extend [
ifEven: evenBlock ifOdd: oddBlock [
^self even
ifTrue: [ evenBlock value: self ]
ifFalse: [ oddBlock value: self ]
]
].

10 ifEven: [ :n | n / 2 ] ifOdd: [ :n | n * 3 + 1 ] "5"
</syntaxhighlight>

搜集类（<code>Collection</code>）的<code>collect:</code>方法，将接收者的每个元素传递给一个块来求值，返回这些结果的搜集。这类似于[[函数式编程]]语言中[[map (高阶函数)|map]]函数。例如计算从<code>1</code>到<code>10</code>的平方：

<syntaxhighlight lang="smalltalk">
(1 to: 10) collect: [ :x | x squared ] "(1 4 9 16 25 36 49 64 81 100 )"
</syntaxhighlight>

可迭代类（<code>Iterable</code>）定义了由子类实现的<code>do:</code>方法，将一个块[[迭代]]于接收者的每个元素之上。这也被称为[[迭代器#隐式迭代器|隐式迭代器]]。例如迭代于数组和区间之上：

<syntaxhighlight lang="smalltalk">
array := #(1 'hi' 3.14e0).
array do: [ :item | item displayNl ].
"=> 1"
"=> hi"
"=> 3.14"

(3 to: 6) do: [ :item | item displayNl ]
"=> 3"
"=> 4"
"=> 5"
"=> 6"
</syntaxhighlight>
可迭代类的<code>inject:into:</code>方法，接受一个参数和一个块二者；它迭代于接收者的每个元素之上，在其上执行某个函数并保持结果为一个聚集。这类似于[[函数式编程]]语言中[[fold (高阶函数)|foldl]]函数。这个方法是凭借调用<code>do:</code>方法实现的。例如：

<syntaxhighlight lang="smalltalk">
#(1 3 5) inject: 10 into: [ :sum :element | sum + element ] "19"
</syntaxhighlight>

在第一个趟时，这个块接受<code>10</code>（要注入的实际参数）作为<code>sum</code> ，和<code>1</code>（这个数组的第一个元素）作为元素，结果为<code>11</code>。<code>11</code>接着成为在下一趟时的<code>sum</code>，这时向它加上<code>3</code>得到<code>14</code>。<code>14</code>接着加上<code>5</code>，最终返回<code>19</code>。

块可以和很多内建方法一起工作，下面例子向一个文件写一行文本，然后再读取它的每一行并显示：

<syntaxhighlight lang="smalltalk">
(File name: 'file.txt') withWriteStreamDo:
[ :file | file nextPutAll: 'Wrote some text.'; nl ]

(File name: 'file.txt') readStream linesDo:
[ :each | each displayNl ] ; close
"=> Wrote some text."
</syntaxhighlight>
文件类（<code>File</code>）的特有于GNU Smalltalk的<code>name:</code>方法，返回具有[[路径 (计算机科学)|绝对路径]]的文件名。GNU Smalltalk有特有的文件路径类（<code>FilePath</code>），它的<code>withWriteStreamDo:</code>方法，对接收者调用<code>writeStream</code>方法打开一个只写的文件串流类（<code>FileStream</code>）实例，在其上调用一个块，并在这个块的动态范围结束处保证（<code>ensure:</code>）关闭这个串流；它的<code>readStream</code>方法，在接收者上打开一个只读的文件串流类（<code>FileStream</code>）实例。

串流类（<code>Stream</code>）的特有于GNU Smalltalk的<code>linesDo:</code>方法，对它的接收者的每一行都求值它的参数块一次。在GNU Smalltalk中，文件串流类（<code>FileStream</code>）的超类，不再是作为可定位串流类（<code>PositionableStream</code>）子类的读写串流类（<code>ReadWriteStream</code>），而是其特有的作为串流类（<code>Stream</code>）子类的文件描述符类（<code>FileDescriptor</code>），它的<code>close</code>方法关闭这个文件。

==类==

GNU Smalltalk建立新类采用特有的语法形式：
<syntaxhighlight lang="smalltalk">
超类名字 subclass: 新类名字 [
| 诸实例变量 |
pragmas
消息模式1 [ 诸语句 ]
消息模式2 [ 诸语句 ]
...
类变量1 := 表达式.
类变量2 := 表达式.
...
]
</syntaxhighlight>
类似的，为现存的类扩展新方法采用特有的语法形式：
<syntaxhighlight lang="smalltalk">
类表达式 extend [
...
]
</syntaxhighlight>
在Smalltalk有关书籍中有一个常见版式约定，将一个类中的方法引用为<code>类名字 >> 方法名字</code>，这不是[[Squeak]]/[[Pharo]]语法的一部份，GNU Smalltalk将<code>类名字 class >> 方法名字</code>作为定义类方法的语法形式。

下面的代码定义叫做<code>Person</code>的一个类，这个类有两个实例变量<code>name</code>和<code>age</code>，它们有各自的[[变异子与访问子]]。定义了有两个关键字参数的[[类方法]]，用来创建新的类实例。定义了单独用<code>age</code>来进行比较的<code><</code>方法，通过从<code>Magnitude</code>派生，这个类自动继承了所有的其他比较方法的定义。这个类还通过覆写<code>printOn:</code>的方式，定制了这个对象的打印（<code>print</code>）/显示（<code>display</code>）方式：

<syntaxhighlight lang="smalltalk">
Magnitude subclass: Person [
| name age |
Person class >> name: name age: age [
^self new name: name; age: age; yourself
]

< aPerson [ ^self age < aPerson age ]
name [ ^name ]
name: value [ name := value ]
age [ ^age ]
age: value [ age := value ]
printOn: aStream [ aStream nextPutAll: ('%1 (%2)' % { name. age }) ]
].

group := {
Person name: 'Dan' age: 23.
Person name: 'Mark' age: 63.
Person name: 'Cod' age: 16
}.

group asSortedCollection reverse
</syntaxhighlight>

这里用<code>asSortedCollection</code>方法对搜集进行排序，然后用<code>reverse</code>方法来做反转。最终结果是按<code>age</code>反序打印了三个人的信息：
<syntaxhighlight lang="text">
OrderedCollection (Mark (63) Dan (23) Cod (16) )
</syntaxhighlight>

==异常==
要发起能够捕获的异常，需要调用异常类（<code>Exception</code>）及其子类的<code>signal</code>或<code>signal:</code>方法。错误类（<code>Error</code>）表示不可恢复的致命错误，警告类（<code>Warning</code>）表示重要但可恢复的错误，停机类（<code>Halt</code>）表示通常是漏洞（bug）的可恢复错误。例如：
<syntaxhighlight lang="smalltalk">
Error signal.
Error signal: 'Illegal arguments!'
</syntaxhighlight>

异常通过块闭包（<code>BlockClosure</code>）的<code>on:do:</code>方法来处理，还可以只捕获特定的异常（和它们的子类）：

<syntaxhighlight lang="smalltalk">
[ 做些事情
] on: Exception do: [ :ex |
处理ex中异常
]

[ 做些事情
] on: Warning do: [ :ex |
处理ex中异常
]
</syntaxhighlight>

处理器子句使用它能获得的异常对象，可以退出或恢复一个块；退出是缺省的，但也可以显式的指示：

<syntaxhighlight lang="smalltalk">
[ Error signal: 'foo'
] on: Error do: [ :ex |
ex return: 5
]

(Warning signal: 'now what?') printNl "=> nil"

[ (Warning signal: 'now what?') printNl
] on: Warning do: [ :ex |
ex resume: 5
] "=> 5"
</syntaxhighlight>

在因异常状况而要进入[[调试器]]，可以调用对象类（<code>Object</code>）的<code>halt</code>方法，或增加了一个消息参数的<code>halt:</code>方法；这二者实际上调用了对象类的<code>error:</code>方法，它通过原始操作停止执行{{le|及或|And/or}}启动调试器，并展示这个错误消息：
<syntaxhighlight lang="smalltalk">
self halt. "halt encountered"
self halt: 'This is a message'.
self error: 'This is a message'
</syntaxhighlight>

== 参见 ==
* {{le|Ruby语法|Ruby syntax}}
* [[解决方案堆栈#GLASS|GLASS]]

==引用==
{{reflist|2}}

== 外部链接 ==
* {{Official website|https://www.gnu.org/software/smalltalk/}}

{{Smalltalk programming language}}
{{GTK|state=collapsed}}
{{GNU|state=collapsed}}

{{DEFAULTSORT:Gnu Smalltalk}}
[[Category:Smalltalk编程语言家族]]
[[Category:GNU计划软件|Smalltalk]]
[[Category:脚本语言]]
[[Category:自由教育软件]]

GNU Smalltalk - 版本历史

2025年12月26日 (五) 18:08 imported>ExultantEditor